前两天一位做销售工作的朋友询问了我一个问题，如何将表格中大量的电话数据批量的导入到苹果手机中。于是，通过搜索找到了一个切实可行的方法，方法分享如下：

新建一个空白Excel，然后将其另存为【启用宏的工作簿(.xlsm)】。

另存为之后，回到Excel，在顶部菜单栏依次点击“开发工具”→“Visual Basic”，或者直接按快捷键“Alt+F11”。

在左侧，双击Sheet1(Sheet1)，并把下面的代码复制到右侧空白处：

'通过ICloud导入通讯录，此文件可批量生成导入的VCF文件

Public Sub 生成通讯录vCard文件()

Dim gPath As String

Dim sFile As Object, Fso As Object

Dim tmpStr As String

Dim lastRowA, lastColumn1 As Integer

Dim i, j As Integer

Dim t As Date

Dim msgresult As VbMsgBoxResult

msgresult = MsgBox("是否生成表头？", vbYesNoCancel, "生成vCard文件(*.vcf)")

If msgresult = vbYes Then

'生成表头

Range("A1") = "姓氏"

Range("b1") = "名字"

Range("c1") = "职务"

Range("d1") = "手机"

Range("f1") = "短号"

Range("g1") = "座机"

Range("h1") = "其他号码"

MsgBox "表头生成完毕，请填完内容后重新点击按钮，并选择[否],开始生成vCard文件"

ElseIf msgresult = vbNo Then

'将生成vCard文件

t = Now() '计时

lastRowA = Range("A1000000").End(xlUp).Row

lastColumn1 = Range("XX1").End(xlToLeft).Column

gPath = CreateObject("WScript.Shell").SpecialFolders("Desktop")

Set Fso = CreateObject("Scripting.FileSystemObject")

Set sFile = Fso.CreateTextFile(gPath & "/" & Format(Now(), "通讯录YYYYMMDDHHmmSS") & ".vcf", True, True)

For i = 2 To lastRowA

tmpStr = "BEGIN:VCARD" & vbCrLf & "VERSION:3.0" & vbCrLf

tmpStr = tmpStr + "N:" & Cells(i, 2) & ";" & Cells(i, 1) & ";;;" & vbCrLf '名字 姓氏

tmpStr = tmpStr + "FN:" & Cells(i, 1) & " " & Cells(i, 2) & ";" & vbCrLf '全名

tmpStr = tmpStr + "ORG:" & Cells(i, 3) & ";" & vbCrLf '公司名称

tmpStr = tmpStr + "TEL;TYPE=CELL;TYPE=pref;TYPE=VOICE:" & Cells(i, 4) & vbCrLf

'扩展其他号码

For j = 6 To lastColumn1

If Cells(i, j) <> "" Then

tmpStr = tmpStr + "item" & j - 5 & ".TEL:" & Cells(i, j).Value & vbCrLf & "item" & j - 5 & ".X-ABLabel:" & Cells(1, j) & vbCrLf

End If

Next

tmpStr = tmpStr + "END:VCARD" & vbCrLf

sFile.WriteLine (tmpStr)

Next

sFile.Close

Set sFile = Nothing

Set Fso = Nothing

MsgBox "耗时：" & DateDiff("s", t, Now()) & "秒" & vbCrLf & "通讯录已生成在桌面，接着请登录ICloud导入。", vbOKOnly, "胖猫提示::"

End If

End Sub

填好代码之后，按Ctrl+S保存一下，然后关闭当前窗口回到excel，在顶部菜单栏点击“视图”→“宏”→“生成通讯录vCard文件”，选是，然后把通讯录复制进去，没有内容就空着，再点击宏选否，将在桌面生成一个以“通讯录”开头，以日期命名的.vcf文件。

然后通过浏览器，登录Icloud，找到“通讯录”

在通讯录的左下角，找到“齿轮”一样的设置图标，点击弹出子菜单，在子菜单找到“导入vCared...”，在弹出的框中，选中生成在桌面的“通讯录....vcf”文件，至此，批量导入通讯录到iphone的操作完毕。（代码部分为转载）